Noxious OT Wiki

Unofficial Noxious Open Tibia Wiki: info, downloads, tools, calculators...

User Tools

Site Tools


ElfBot Combo Multi-Client Leader Scripts

By now you've already mastered Cavebot and Targeting and you want to take your botting skills to the next level.

Enter Multi-Client Combo! Several bots working automatically as a team while you control the Leader. As the Leader, you will guide everyone and decide where to go and what to do. Thanks to this, you will be able to explore and hunt in places you could never go alone!

The tasks that we'll teach your team of bots (Followers from now on) are:

  1. (Automatic): Heal team members
  2. follow / wait: Follow the Leader
  3. attack / stop: : Attack enemies
  4. Other tasks
    • pick: Pick up items
    • drop ITEMID: Drop certain items
    • attack PERSONNAME: Attack a specific person/creature
    • do logout: Everything else (talk in chat, logout, turn east, etc.)

We have made it as simple as possible while keeping it super powerful and versatile, so don't worry, you will both understand how it works as well as benefit from it.

Followers will only listen to his assigned Leader so always make sure to talk as the Leader. If you have subordinates, you could send a PM to a sub-leader with do say 'stop' , which he would then say stop and his Followers would obey him.

Following the Leader

That's pretty easy, we tell the Followers to follow NAMEOFLEADER when they're not attacking, if the Leader has disappeared, it will try to use a rope, then ladder, then keep walking on the same direction and try a rope, then a ladder, etc. This way, bots will always follow the Leader even when they go up or down a floor. The only thing you need to remember is that Followers need to face the ladder/stairs or they will keep walking straight. You can always say do turne to make them turn to the East.

set $leader 'NAMEOFLEADER'
set $f '0'
auto 500 listas 'Follow Leader' | if [isnottargeting && $standtime > 1000 && $f == '1'] { follow '$' | isnotonscreen '$' {say 'exani tera' | usegroundxyz $self.posx $self.posy $self.posz | race } }else{ stopattack }

Heal teammates

Now's the time to heal your teammates, start with the most important guy (Leader probably) first.

auto 200 | set $tm $creature.'TEAMMATE1' | if ['$tm.hppc' < 66] { safe uh '$' }
auto 200 | set $tm $creature.'TEAMMATE2' | if ['$tm.hppc' < 66] { safe uh '$' }
auto 200 | set $tm $creature.'TEAMMATE3' | if ['$tm.hppc' < 66] { safe uh '$' }
auto 200 | set $tm $creature.'TEAMMATE4' | if ['$tm.hppc' < 66] { safe uh '$' }

How it works is that it will first try and heal TEAMMATE1, if he doesn't need to then it will try to heal the next one and so on. If two or more teammates need it, it will heal the first one from the list (and then be exhausted) so the most top teammate will be healed and the other teammates will need to wait.

You may rotate the list amongst all your teammates so everyone is someone's top priority.

Attack monsters

There's tons of websites on the Internet explaining complicated scripts that do this and that, and sounds great and super cool. But these scripts are just complicating and replicating what we already have very well implemented. We've been attacking enemies automatically until now, so…

Use Targeting! You just need to activate Run Targeting for each of your Followers and configure each one to use the Attack and Spells/Runes you want, job done. Followers will attack as your Targeting settings order and when no more enemies are present, they will get back to following the Leader.

You can use chat commands to further control the Followers, one that's very useful is to control if he wants Followers to attack. When the Leader says attack, they will turn on Targeting, when he says stop, they will stop Targeting:

auto 500 listas 'Listen Leader' | if [$lastmsg.sender == $ && $lastmsg.content != $m]{ set $m $lastmsg.content }else{ set $m '' } | if [$m == 'stop']{ settargeting off } | if [$m == 'attack']{ settargeting on } | if [$cutstr.'$m'.1.7 == 'attack ']{ set $name $cutstr.'$m'.8 | attack $name | wait 5000 } | if [$m == 'pick']{ pickupitems 'empty' | wait 5000 } | if [$cutstr.'$m'.1.4 == 'drop']{ set $id $cutstr.'$m'.6 | dropitems $id | wait 5000 } | if [$cutstr.'$m'.1.3 == 'do ']{ set $c $cutstr.'$m'.4 | exec $c | wait 5000 } | if [$m == 'wait']{ set $f '0' } | if [$m == 'follow']{ set $f '1' }

If you just want one of the Followers to follow a chat command, talk to them in a Private Message. You can create channels of specific Followers to do certain things (e.g. All mages to wait at the entrance).

Other tasks


You can also have your teammates loot monsters if you'd like with the Targeting options.

Pick items from the ground

You might want to give your Followers items to carry, Potions or Food, add this script to the Listen Leader and when the Leader says pick, the Followers will grab whatever is below them:

| if [$m == 'pick']{ pickupitems 'empty' }

Drop items to the ground

You might want your Followers to give you something: Potions, Food or Money, add this script to the Listen Leader and when the Leader says drop ITEMID, the Followers will drop a stack (0-100) of that item below them:

| if [$cutstr.'$m'.1.4 == 'drop']{ set $id $cutstr.'$m'.6 | dropitems $id }

Defending from a PK

The first script allows the Leader to say attack Bubble which will make Followers attack Bubble

| if [$cutstr.'$m'.1.7 == 'attack ']{ set $name $cutstr.'$m'.8 | attack $name }

The following script will detect a player with a skull and attack him:

(coming soon)

Doing anything else

You can do pretty much anything with this script, for example, if you say do turne, Followers will turne (turn to the East):

| if [$cutstr.'$m'.1.3 == 'do ']{ set $c $cutstr.'$m'.4 | exec $c }

This chat order is very powerful, you can do pretty much anything (say something in chat, logout, etc.). Remember that you can order only to some Followers by talking to them through a Private Message.

Stop following

| if [$m == 'wait']{ set $f '0' } | if [$m == 'follow']{ set $f '1' }

Go back to ElfBot.

You could leave a comment if you were logged in.